自从改版之后，因为巨集的写法有很大的改变，似乎有不少人哇哇叫的样子
在此列出一些范例，如果有问题欢迎提出来讨论

如果需要详细的资讯的话，推荐参考以下连结
WOW API
HOWTO: Make a Macro
2.0 consolidated changes




但是在提出之前，请先看看以下这几点，这边先列两种常常会被问的问题：

一、因为CastSpellByName()跟TargetUnit()这两个指令被禁止用在巨集之中，所以有关判断任何目标的体力、魔力、buff、debuff的功能，皆不能与技能作组合，讲得白话点，也就是不能再以判断目标的体力、魔力，或是有没有中何种buff、debuff，来决定该使用什么技能。

二、大部分的技能会触发GCD（共同冷却），而且不论是否施展成功都会触发，所以不能将两个会受到GCD影响的技能放在一起，然后期许因为第一个技能还不能使用而去使用第二技能。举个简单的例子，如果把破甲放在复仇的后面，不管复仇是不是可用，都保证破甲绝对用不出来。

如果说你的巨集跟上面两种之一有关的话
必须要修改成以玩家自己判断状况的巨集
若坚持要保有原来的功能…
很对不起，那是无解的，请别提出来了


继续追加常常被问的问题：

三、如果巨集没有办法显示CD时间与说明，在巨集开始第一行加入以下这行即可

# showtooltip 道具或技能名称

顺便一提，现在设定巨集图案(ICON)的时候，如果选择第一个？图案，而在巨集中又有# showtooltip或# show等指令的话，会自动对应成指定的道具或技能图案。如果仅选择第一个？图案，而在巨集中没有# showtooltip或# show等指令的话，则会选择第一个/cast或/use系列中所指示的第一个技能或物品作为图案。



========================== 废话到此为止 ==============================
=============== 应该有不少人会直接略过上面直接往下看吧 ===============

通用的巨集：

发动攻击，此巨集不会因为多点了一下而取消攻击动作，要取消请爱用ESC。
# showtooltip 攻击
/startattack


设定一个目标作为『focus』的对象。
顾名思义，『focus』就是设定用来『监控』一个目标。如此一来，即使目标常常换来换去，依然可以非常迅速地『监控』一个重要的目标，对于控场及治疗有着很大的帮助。
/focus
/s %t！我正在监视你！


使用厚符文布绷带。若是以右键点击，则为自己的宠物使用；若不是以右键点击，则是为一个友善的目标使用；若没有友善目标，则是为自己使用。
/use [target=pet,button:2] 厚符文布绷带;[help] 厚符文布绷带; [target=player] 厚符文布绷带


依序使用寻找药草、寻找矿石，依此轮回。此巨集只会在没有进入战斗时使用以避免触发GCD。
亦可将各种职业或种族的追踪技能追加进去，如寻找宝箱、追踪野兽等。
/castsequence [nocombat] 寻找草药, 寻找矿物


取消一个Buff。除了坐骑以外都可以用这个。
/cancelaura Buff名称


随机选择坐骑；若已经在骑乘状态则解除坐骑。并在使用坐骑时讲话。
/dismount [mounted]
/userandom [nomounted,nocombat,outdoors] 迅捷祖利安猛虎, 拉札希迅猛龙, 迅捷雾刃豹缰绳, 死亡军马的缰绳
/script if not IsMounted() then SendChatMessage("让我想想…该用骑那一头坐骑好呢…", "SAY");end;


装备指定物品。
主手物品必须比副手物品先行装备，否则从双手武器切换时会有问题。
/equipslot 11 戒指１
/equipslot 12 戒指２
/equipslot 13 饰品１
/equipslot 14 饰品２
/equipslot 16 主手装备
/equipslot 17 副手装备


使用钓鱼，若尚未装备钓鱼竿则装备钓鱼竿。如果以右键点击，则是装备回指定的武器。
/equip [nobutton:2,noequipped:鱼竿] 钓鱼竿
/cast [nobutton:2,equipped:鱼竿] 钓鱼
/equipslot [button:2] 16 主手装备
/equipslot [button:2] 17 副手装备



战士巨集：

依照姿态的不同使用反击风暴、盾墙或鲁莽。同时大喊通知他人。
/cast [stance:1] 反击风暴;[stance:2,equipped:盾牌] 盾墙;[stance:3] 鲁莽
/script s={"反击风暴！谁想挨揍的啊！","盾墙！硬梆梆的15秒！","鲁莽！不要拦我！"};SendChatMessage(s[GetShapeshiftForm(true)], "YELL");


使用嘲讽，并在使用之前切换为防御姿态（如果必要的话）。
# showtooltip 嘲讽
/cast [stance:2] 嘲讽; 防御姿态

其他像压制、拳击、缴械等技能也可以照样修改，注意[stance:1]是战斗姿态。[stance:3]是狂暴姿态
# showtooltip 惩戒痛击
/cast [stance:1] 惩戒痛击; 战斗姿态

# showtooltip 狂暴之怒
/cast [stance:3] 狂暴之怒; 狂暴姿态


在切换至战斗姿态以及装备指定武器之后，使用压制。
旋风斩也是一样的格式，这里就不列了。
# showtooltip 压制
/equip [noequipped:双手]爽手武器
/cast [stance:1,equipped:双手] 压制;[nostance:1] 战斗姿态


使用挫志怒吼，若是以右键点击则使用雷霆一击。
# showtooltip 雷霆一击
/cast [button:2] 雷霆一击; 挫志怒吼


若进入战斗状态，则使用压制；否则使用冲锋。若是以右键点击则同时使用英勇打击。
# showtooltip 压制
/cast [combat] 压制; 冲锋
/stopcasting [button:2]
/cast [button:2] 英勇打击


使用致死打击，若致死打击尚在冷却时间内则使用旋风斩。
有点强化致死的话，记得把6改成5。
/castsequence reset=6 致死打击, 旋风斩


同时使用英勇打击及破甲攻击。
由于英勇打击没有GCD的问题，所以可以跟其他瞬发技能一起使用。
当然，怒气要足够～
# showtooltip 破甲攻击
/cast 破甲攻击
/stopcasting
/cast 英勇打击

或者下面这个也是可行的，交替使用二个，只要狂按就好。
# showtooltip 破甲攻击
/castsequence 英勇打击, 破甲攻击


如果有装备盾而且是在战斗或防御姿态就使用盾击；否则使用拳击，并于使用前切换到狂暴姿态（如果有必要的话）。
# showtooltip 拳击
/cast [stance:1/2,equipped:盾牌] 盾击;[stance:1/2,noequipped:盾牌] 狂暴姿态; 拳击


若尚未进入战斗时切换为战斗姿态（如果必要的话），并使用冲锋；若已经进入战斗时切换为狂暴姿态（如果必要的话），并使用拦截。
# showtooltip 拦截
/cast [stance:1,nocombat] 冲锋;[nocombat] 战斗姿态; [stance:1/2] 狂暴姿态; 拦截


若『滑鼠所指的目标』为敌对目标，则对该目标使用破甲攻击；否则对『眼前的目标』使用破甲攻击。
透过这样的实作就能在不需更换眼前的目标的前提下，对其他目标使用破甲攻击。由于破甲攻击没有伤害的特性，所以即使用在被牵制（变形、媚惑…）的目标上也不会造成牵制失效。
# showtooltip 破甲攻击
/cast [target=mouseover,exists,harm] 破甲攻击; 破甲攻击



牧师巨集：

使用复活术并通知他人。
台词过长可能会发生问题，若出现错误讯息时试着缩短台词或减少台词种类即可。
# showtooltip 复活术
/script s={"台词一","台词二","台词三","台词四"};
/script if UnitExists("target") and UnitIsDeadOrGhost("target") then SendChatMessage(s[math.random(getn(s))], "SAY");end;
/cast 复活术


使用真言术：韧；若以右键点击则使用坚韧祷言。
# showtooltip 坚韧祷言
/cast [button:2] 坚韧祷言; 真言术：韧


立即停止目前动作并使用沉默；如果目标不是敌对状态，就对目标的目标使用（目标的目标必须为敌对状态）。
# showtooltip 沉默
/stopcasting
/cast [harm] 沉默; [target=targettarget,harm] 沉默


对友善目标或敌对目标的友善目标使用强效治疗术；若以右键点击则对自己使用强效治疗术。
# showtooltip 强效治疗术
/cast [target=player,button:2] 强效治疗术;[help] 强效治疗术; [target=targettarget,help] 强效治疗术


将『眼前的目标』设定为『监控的目标』并使用束缚不死生物。若以右键点击，则直接对『监控的目标』使用束缚不死生物（若『监控的目标』已死亡或不存在，会自动将『眼前的目标』设定为『监控的目标』）。
透过这样的实作之后，只需要在第一次进行束缚的时候注视着该目标，第二次之后就不必转头去看也能够直接进行束缚。
# showtooltip 束缚不死生物
/clearfocus [target=focus,dead]
/clearfocus [target=focus,noexists]
/focus [nobutton:2]
/focus [target=focus,noexists,button:2]
/cast [target=focus,button:2] 束缚不死生物; 束缚不死生物
/script SendChatMessage("正在对 "..UnitName("focus").." 施放束缚不死生物
","SAY");



猎人巨集：

使用猎豹守护，如果是以右键点击则使用豹群守护。
# showtooltip 豹群守护
/cast [button:2] 豹群守护; 猎豹守护


使用毒蛇钉刺，如果是以右键点击则使用蝮蛇钉刺，如果是以中键点击则使用毒蝎钉刺。
# showtooltip 毒蛇钉刺
/cast [button:3] 毒蝎钉刺;[button:2] 蝮蛇钉刺; 毒蛇钉刺


使用假死，若假死尚在冷却时间内则使用逃脱。战斗脱离之后自动重置。
# showtooltip 假死
/castsequence reset=30/combat 假死, 逃脱, 逃脱, 逃脱, 逃脱


对敌对目标使用猎人印记。若是以右键点击，则同时命令宠物攻击。若是在队伍中，则通知队友被标印记的目标为何。
若将「/stopmacro [nogroup]」改成「/stopmacro [nogroup:raid]」，则只有在raid中才会通知队友。
# showtooltip 猎人印记
/cast [harm] 猎人印记
/stopmacro [noharm]
/petattack [pet,button:2]
/stopmacro [nogroup]
/y 攻击目标为 %t


同时使用猛禽一击及摔绊。
# showtooltip 猛禽一击
/cast 摔绊
/stopcasting
/cast 猛禽一击


如果以右键点击或宠物虽存在但已死亡，使用复活宠物；如果宠物不存在，使用召唤宠物；如果宠物存在且在战斗中，使用治疗宠物；如果宠物存在且不在战斗中，使用喂食宠物并使用指定食物。
# showtooltip 治疗宠物
/cast [button:2,nocombat] 复活宠物;[target=pet,dead,nocombat] 复活宠物;[nopet] 召唤宠物;[combat] 治疗宠物; 喂养宠物
/use [pet,nocombat] 食物名称


命令宠物攻击或协同同伴攻击；如果以右键点击则是召回宠物。
/petfollow [button:2]
/stopmacro [button:2]
/stopmacro [noexists]
/assist [help]
/petattack


将『眼前友善目标』设为『监控的目标』，如果『眼前的目标』并非友善目标，则将『目标的目标』设为『监控的目标』，同时使用误导。
# showtooltip 误导
/clearfocus [target=focus,dead]
/clearfocus [target=focus,noexists]
/focus [help]
/focus [target=focus,noexists] targettarget
/clearfocus [target=focus,harm]
/cast [target=focus,exists] 误导



圣骑士巨集：

使用力量祝福；如果以右键点击则使用强效力量祝福。
# showtooltip 强效力量祝福
/cast [button:2] 强效力量祝福; 力量祝福


对友善目标或敌对目标的友善目标使用圣光术；如果以右键点击则对自己使用。
# showtooltip 圣光术
/cast [target=player,button:2] 圣光术;[help] 圣光术; [target=targettarget,help] 圣光术


对友善目标或敌对目标的友善目标使用正义防御。
# showtooltip 正义防御
/cast [help] 正义防御;[target=targettarget,help] 正义防御


对敌对目标使用神圣震击；或以右键点击队友善目标使用。
# showtooltip 神圣震击
/cast [button:2,help] 神圣震击;[harm] 神圣震击


使用神恩术，并对敌对目标使用神圣震击。若以右键点击，则对友善目标使用神震击。
# showtooltip 神恩术
/cast 神恩术
/stopcasting
/stopmacro [dead]
/cast [harm] 神圣震击;[help,button:2] 神圣震击



术士巨集：

用右键就是使用极效灵魂石；否则就是制造极效灵魂石。
# showtooltip 极效灵魂石
/cast [nobutton:2] 制造灵魂石
/stopmacro [nobutton:2]
/use [help] 极效灵魂石
/stopmacro [nohelp]
/y >>>%t<<<已经被我绑定了


若以右键点击则对监控的目标使用诅咒三连星；否则眼前的目标使用诅咒三连星，同时将监控眼前的目标。
/clearfocus [target=focus,dead]
/clearfocus [target=focus,noexists]
/focus [nobutton:2]
/focus [target=focus,noexists,button:2]
/castsequence [target=focus,button:2] reset=combat/target 痛苦诅咒,腐蚀术,献祭; reset=combat/target 痛苦诅咒,腐蚀术,献祭



感谢巴哈-thundermare-大大